电子表格中的函数使用

补充 SUMPRODUCT 使用 #

按月份及另外的匹配条件去求和：
SUMPRODUCT((MONTH(D2:D10)=G2)*(B2:B10=F2)*C2:C10)
上面条件的变化形式——条件内有文本字符和方便下拉填充： SUMPRODUCT((MONTH($D$2:$D$10)&"月"=G$1)*($B$2:$B$10=$F2)*$C$2:$C$10) 说明：数据区域 $B$2:$B$10 完全引用，名称 $F2 锁列不锁行，月份 G$1 锁行不锁列，向下填充不改变，向右填充才改变。

统计两个日期间数据和：
SUMIFS($D$21:$D$216,$A$21:$A$216,">="&DATE(2024,9,9),A21:A216,"<=2024-12-15")
上面混用了两种日期的处理方法，只是为了节省示例数量。

统计不重复数量公式：
=SUMPRODUCT(1/COUNTIF(A2:A320,A2:A320))
=SUMPRODUCT(N(MATCH(A2:A320,A2:A320,0)=ROW(A2:A320)-1))

& 连接符的使用 #

用于将多个单元格的文本内容合并为一个字符串，可以快速拼接姓名、地址、标签等，支持添加自定义分隔符。
=A2&"文本内容或分隔符"&B2
="Today is "&TEXT(TODAY(),"dddd,mmmm dd") 结合其它函数的使用（或 TEXT(TODAY(),"yyyy-mm-dd")），显示“今天是……”

取整数的函数 #

TRUNC(数字，取整精度的数字-默认为0-可选项)

TRUNC 和 INT 是相似的函数，因为它们都返回整数。 TRUNC 只是删除数字的小数部分，而 INT 返回最接近的下限整数 (不一定在数量级) 较小。 负数出现差异：TRUNC (-4.3) 返回 -4，但 INT (-4.3) 返回 -5，因为 -5 是较低的数字。

INT (数字)
“数字”是要向下舍入为整数的实数。

日期计算 #

如果要计算两个日期之间的天数，最简单的方法就是日期直接相减。

计算两个日期之间相隔的天数、月数或年数：
DATEDIF(start_date,end_date,参数)
参数用来定义要返回的信息类型：

• “Y” 一段时期内的整年数，忽略不足的年；
• “M” 一段时期内的整月数，忽略不足月；
• “D” 一段时期内的天数；
• “YM” 开始与结束日期之间的月份差，忽略日期中的天和年份；

日期存储为可用于计算的序列号。 默认情况下，1900 年 1 月 1 日的序列号为 1（Excel，可能不同软件有小差异）
DATEDIF 函数在用于计算年龄的公式中很有用。

YEARFRAC(start_date, end_date, 日计数基准-可选)
计算两个日期之间的天数（取整天数）占一年的比例。
可选参数：
0 或省略 US (NASD) 30/360
1 实际/实际
2 实际/360
3 实际/365
日期不能以文本形式输入。

统计列不为空的个数 #

‌COUNTA 函数可以快速计算指定范围内所有非空单元格的数量，包括文本、数字、日期等任何非空白值，可以包括空值。
基本语法‌：=COUNTA(range)，其中 range 为要统计的单元格区域（例如 A2:A100）。‌‌
‌示例‌： =COUNTA(F21:F216)
‌注意事项‌：COUNTA 会将包含空格、文本或公式返回空字符串的单元格视为非空，因此可能高估实际非空值。‌‌

COUNT：若需仅统计数字或日期，应改用 COUNT 函数。‌‌
=COUNT(D21:D216)

‌COUNTBLANK‌：用于统计空单元格数量，与 COUNTA 互补。
例如 =COUNTBLANK(F21:F216) 可帮助验证数据完整性。‌‌

COUNTIF：对满足指定条件的单元格进行计数，要输入多个条件，改用 COUNTIFS 函数

将分钟转化为小时分钟 #

在 Excel 中将分钟数换算为“xx小时xx分钟”的格式（如 150 分钟转为 2 小时 30 分钟），‌最直接的方法是使用公式 =INT(A1/60)&"小时"&MOD(A1,60)&"分钟"，其中 A1 为包含分钟数的单元格‌。该公式通过整数除法计算小时数，取余数获取剩余分钟数，并拼接文本输出结果。‌‌

其它 #

取最大值： =MAX(B21:B216)

按年月统计求和两例，A 列单元格为“6月份总计”形式：
=SUMPRODUCT((YEAR(A21:A192)=2025)*(MONTH(A21:A192)=6)*1,F21:F192)
=SUMPRODUCT((YEAR($A$21:$A$192)=2025)*(MONTH($A$21:$A$192)=VALUE(LEFT(A10,2*LEN(A10)-LENB(A10))))*1,$F$21:$F$192)
按年月统计次数两例：
=SUMPRODUCT(--(YEAR(A21:A192)=2025)*(MONTH(A21:A192)=6))
=SUMPRODUCT((YEAR($A$21:$A$192)=2025)*(MONTH($A$21:$A$192)=VALUE(LEFT(A10,2*LEN(A10)-LENB(A10))))*1)